AROS-Exec :: Forum

Re: coding strategy for big gfx memory usage [by PortablE]

Mon, 06 May 2013 08:49:50 +1700

PortablE:: coding strategy for big gfx memory usage
Mr Darek reported that non-drawable bitmaps still appeared to be using video memory. I have now found & fixed the problem, and it should be included with the next beta release of PortablE.

HOW TO GET A QUICK REPLY to your question [by PortablE]

Thu, 11 Apr 2013 18:33:09 +1700

PortablE:: HOW TO GET A QUICK REPLY to your question
If you are asking a question by creating a new thread, I may not notice your post immediately. To ensure that I do notice it, please ALSO post a reply on this thread - then I will get an email notification (and so check this forum ASAP).

But please ONLY do this for a NEW thread (i.e. the first post), because once I have replied to that new thread, I will get email notifications of any further replies anyway (without you having to post to this thread too).

Re: my beginners program using classes [by PortablE]

Sun, 24 Mar 2013 23:03:36 +1700

PortablE:: my beginners program using classes
Quote:

but compilator say: strangefigures = unknown basic type
how modify program to create global object visible in other procedures.

Make sure that you declare your "strangefigures" class before you use it with a global variable. In other words:

Quote:

CLASS strangefigures
...
ENDCLASS
...
DEF mycircle:PTR TO strangefigures

Does that help?

Re: how opening fullscreen or window mode in one application [by PortablE]

Sun, 10 Mar 2013 21:02:21 +1700

PortablE:: how opening fullscreen or window mode in one application
@mrdarek
PortablE's modules were not really designed for switching between Full Screen & Windowed modes, but it is possible with a little difficulty. I could not put the "secret code" where you wanted, but my example is hopefully not too hard to follow. Basically you have to close your program & then restart it, to change between Full Screen & Windowed modes.
Quote:

MODULE 'std/cGfxSimple'
MODULE 'std/cGui'
MODULE 'std/cAppSimple'

PROC main()
	DEF menuglowne:PTR TO cGuiWindow
	DEF guiPages:PTR TO cGuiGroupPage
	DEF item:PTR TO cGuiItem
	
	DEF newstartmenu:PTR TO cGuiItem
	DEF guiWindow:PTR TO cGuiButton
	DEF guiFull:PTR TO cGuiButton
	
	DEF quit:BOOL
	DEF restart:BOOL, fullScreen:BOOL, app:PTR TO cApp
	
	fullScreen := FALSE		->initial mode
	
	restart := FALSE
	REPEAT
		->specify whether your app is Full Screen or not
		->this must be at the start of your program, otherwise you may easily cause a crash
		IF restart THEN DestroyApp()	->BEWARE: This destroys any windows/bitmaps/sounds/etc that still exist
		app := CreateApp('simplestart')
		IF fullScreen THEN app.initFullWindow()
		app.build()
		
		->do Graphics stuff (but only if we were restarted - due to a button being pressed)
		IF restart
			gfx := CreateGfxWindow(NILA)
			IF fullScreen THEN OpenFull() ELSE OpenWindow(800,600)
			
			mainutility()
			
			CloseWindow()
			gfx := DestroyGfxWindow(gfx)
		ENDIF
		
		->open GUI window
		menuglowne := CreateGuiWindow('simplestart')
		guiPages := menuglowne.beginGroupPage()
		
			newstartmenu := menuglowne.beginGroupVertical()
				menuglowne.addLabel('Simple start').initAlignCenter()	-># a better way to center text! #
				menuglowne.addLabel('                                         ')
				guiWindow := menuglowne.addButton('window mode')
				menuglowne.addLabel(' ')
				guiFull := menuglowne.addButton('fullscreen mode')
				menuglowne.addLabel(' ')
			menuglowne.endGroup() -> newstartmenu
		
		menuglowne.endGroup() ->for Pages
		
		menuglowne.build(FALSE) -> show it now
		
		->GUI event loop
		restart := FALSE
		quit := FALSE
		REPEAT
			item := WaitForChangedGuiItem()
			SELECT item
			CASE NIL
				->(a non-item event occured) so check if user tried to close the window
				IF menuglowne.getCloseRequest()
					IF (guiPages.getState()=0)
						menuglowne.close()
						quit := TRUE
					ELSE
						guiPages.setStateItem(newstartmenu) 
					ENDIF
				ENDIF
				
			CASE guiWindow
				menuglowne.close()
				restart    := TRUE
				fullScreen := FALSE
				
			CASE guiFull
				menuglowne.close()
				restart    := TRUE
				fullScreen := TRUE
			ENDSELECT
		UNTIL quit OR restart
		
		->this is optional, since DestroyApp() will destroy our window anyway...
		->...but it is a good idea, as it makes clearer what is happening
		menuglowne := DestroyGuiWindow(menuglowne)
	UNTIL quit
FINALLY
	PrintException()
ENDPROC

PROC mainutility()
	Pause(3*10)
ENDPROC

Rounding floating-point numbers (and printing them) [by PortablE]

Sun, 03 Mar 2013 17:35:49 +1700

PortablE:: Rounding floating-point numbers (and printing them)
MrDarek asked this: Quote:

I need round function for float values. In documentations I found Ffloor and Fceil function - they are great and very useful but I need also Fround. For example Fround(3.4)=3 Fround(3.5)=4 Fround(3.9)=4

Implementing fround() is very easy. Here is the code for it, along with a program to test it works as expected:
Quote:

PROC fround(value:FLOAT) IS IF value>=0 THEN Ffloor(value+0.5) ELSE Fceil(value-0.5)


PROC main()
	test(3.0)
	test(3.4)
	test(3.5)
	test(3.9)
	test(-3.9)
	test(-3.1)
FINALLY
	PrintException()
ENDPROC

PROC test(value:FLOAT)
	printFloat(value, 'fround(', ') = ')
	printFloat(fround(value))
ENDPROC

PROC printFloat(value:FLOAT, before=NILA:ARRAY OF CHAR, after=NILA:ARRAY OF CHAR, decimalPlaces=6)
	DEF valueStr:STRING, intSize
	
	intSize := Ffloor(Flog10(Fabs(value)))+1 !!VALUE
	NEW valueStr[1+intSize+1+decimalPlaces]
	RealF(valueStr, value, decimalPlaces)
	
	IF before = NILA THEN before := ''
	IF after  = NILA THEN after  := '\n'
	Print('\s\s\s', before, valueStr, after)
FINALLY
	END valueStr
ENDPROC

You may also find the printFloat() procedure useful, as it gives an easy way to print a floating-point number.

Re: MUI-Demo.e doesn't compile under MorphOS [by PortablE]

Wed, 09 Jan 2013 17:07:58 +1700

PortablE:: MUI-Demo.e doesn't compile under MorphOS
@SamuraiCrow
Thanks for your report. Having looked at it, this was due to a small error in the 'libraries/gadtools' module for MorphOS, which I have now fixed. If you need this fix before the next (beta) release of PortablE, then please let me know.

AnnPEGCC - compile PortablE programs inside Annotate [by PortablE]

Sat, 08 Dec 2012 16:04:38 +1700

PortablE:: AnnPEGCC - compile PortablE programs inside Annotate
Thanks to the release of Annotate v3.0.1, I am finally able to release a little program I wrote which allows you to compile PortablE code from inside the Annotate editor. So for example, say you are editing the code "MyBrilliantGame.e", then you can go to Annotate's Tools menu, and choose "PEGCC & Run" to compile & run it

While I personally prefer to compile & run stuff from the Shell, quite a few people have asked for this, so here it finally is!

You can download it from here:
http://cshandley.co.uk/temp/AnnPEGCC_r1.lha

It works on AmigaOS4 & AROS. It will hopefully also work on MorphOS, although this is sadly untested (due to my non-booting Efika).

Don't forget to download Annotate v3.0.1 if you don't have it:
http://www.onyxsoft.se/annotate.html

As this is the first release, please let me know if you have any problems with it...

Re: 2D arrays (2D tables) [by PortablE]

Sun, 04 Nov 2012 12:08:01 +1700

PortablE:: 2D arrays (2D tables)
@mrdarek
By "Integral" I assume you actually mean "Integer"? i.e. An INT, which holds a value between -32768 & 32767.

The modules I supplied can only store VALUEs, which is ideal for holding (A)RGB values & other things. But if you really need to only store values between -32768 & 32767, then it won't be very efficient.

The modules need a few trivial changes to use INT instead of VALUE. I also renamed the objects & procedures to avoid clashing with the original modules. I have attached these new modules (note that these will NOT be included with a future release of PortablE, but they should continue to work).

I recommend that you use the 'CSH/cTable2Dint' module, as this is easier to use & still pretty fast. Here is a little example of it's usage:
Quote:

MODULE 'CSH/cTable2Dint'

PROC main()
	DEF mytable:PTR TO cTable2Dint, copy:PTR TO cTable2Dint
	
	->first table
	NEW mytable.new(10, 15)	->table 10 wide, 15 high
	
	mytable.set(9, 14, 999)
	Print('mytable get=\d \n', mytable.get(9, 14))
	
	->second table
	NEW copy.new(10, 15)
	
	mytable.copyTo(copy)
	Print('copy get=\d \n', copy.get(9, 14))
FINALLY
	PrintException()
	
	END mytable, copy
ENDPROC

Each cTable2Dint is basically just a wrapper for an oTable2DintFast, and you can access that if you want. This means that you can use the friendlier cTable2Dint, but use procedures from pTable2DintFast when you need extra speed. For example:
Quote:

MODULE 'CSH/cTable2Dint', 'CSH/pTable2DintFast'

PROC main()
	DEF mytable:PTR TO cTable2Dint, fast:PTR TO oTable2DintFast
	DEF width, height, x, y, i
	
	->create cTable2Dint
	width  := 10
	height := 15
	NEW mytable.new(width, height)
	
	Print('mytable get=\d \n', mytable.get(width-1, height-1))
	
	->now use pTable2DintFast procedures for extra-fast access
	fast := mytable.fast
	i := 0
	FOR y := 0 TO height-1
		FOR x := 0 TO width-1
			table2Dint_set(fast, x, y, i++)
		ENDFOR
	ENDFOR
	
	Print('mytable get=\d \n', mytable.get(width-1, height-1))
FINALLY
	PrintException()
	
	END mytable
ENDPROC

Re: New release of PortablE aimed at beginners [by PortablE]

Wed, 10 Oct 2012 18:38:38 +1700

PortablE:: New release of PortablE aimed at beginners
I have uploaded a new PortablE beta archive with a very small fix (almost cosmetic):

* When the installer deletes obsolete modules, it will no-longer fail to delete a couple of folders (which was harmless but might have worried some people).
* A small 'bonus' is that the installer will now delete a few obsolete modules that I had previously overlooked.

Users who have already installed the latest release of PortablE do NOT need to download it again!

Re: help in portable arrays need [by PortablE]

Sat, 29 Sep 2012 10:05:13 +1700

PortablE:: help in portable arrays need
If anyone wants an easier (but less flexible) alternative for 2D arrays, which can only store VALUEs (rather than BYTEs, STRINGs, or whatever), then I have created a couple of nice modules:
http://aros-exec.org/modules/newbb/viewtopic.php?post_id=74208